Conservation laws

We solve a problem of ballistics using energy and momentum conservation. A bullet of mass m is shot into a suspended sand box of mass M . The aim is to determine the initial speed of the bullet v 0 from the motion of the combined sandbox/bullet system that acquires the final velocity V .

The exercise will help us to understand how the solve command works in Maple. We will also learn how to scale variables in such a way that the results can be graphed without making assumptions about numerical values for the parameters in the problem. This represents a very useful trick for many applications.

The two equations required are the energy conservation and momentum conservation laws. We include the conversion of some mechancial energy into heat, i.e., we assume that a part of the bullet's kinetic energy is converted into translational (kinetic) energy of the system M+m , and a fraction goes into heating the sand while the bullet is slowed down from the velocity v 0 to V . The latter is labeled as Q . The conditions are called inelastic, as some mechanical energy is removed from the system.

The energy conservation law states that the kinetic energy of the bullet before it hits the suspended sandbox equals the kinetic energy of the combined system after the hit plus the amount of heat produced by the slow-down of the bullet inside the box (friction).

> En:=m/2*v0^2=(M+m)/2*V^2+Q;

Momentum conservation is stated as follows:

> Mom:=m*v0=(M+m)*V;

We solve the pair of equations for the final velocity and the unknown heat:

> sol:=solve({En,Mom},{V,Q});

From this result it is evident that the determination of the final velocity (e.g., from the amplitude of the suspended sand box motion), and knowledge of both masses m and M permits to determine the initial velocity v 0. This information is contained in the first part of the solution. Let us extract it:

> nops(sol);

> sol[1];

> solve(%,v0);

We assume a mass of the sand box 1000 times larger than for the bullet, e.g., 5 kg and 5 g respectively:

> subs(M=1000*m,%);

From the above we realize that we need to know the mass ratio of the sand box and bullet masses to obtain the relationship of initial bullet and final sand box/bullet velocities.

An interesting conclusion concerns the fraction of the bullet's initial kinetic energy converted to heat.

> sol[2];

We follow the technique of assigning the solution. This fixes the variable Q in our case:

> assign(sol[2]);

> Q;

> fr:=subs(M=1000*m,Q)/(m/2*v0^2);

We observe that the majority of the bullet's kinetic energy was used up to heat the sand box.

Let us look at the fraction in general:

> fr:=Q/(m/2*v0^2);

How would we express this fraction as a function of the mass ratio r = M / m ?

> fr1:=subs(M=m*r,fr);

> fr1:=simplify(fr1);

> with(plots):

> semilogplot(fr1,r=1..1000);

The fact that for mass ratios r = M / m of the order of 100 or more the collision is entirely inelastic becomes obvious from the graph. One can make use of this fact and solve the problem approximately by momentum conservation alone (once on the RHS of the energy conservation law Q dominates completely, the other term can be ignored, and the equation becomes redundant in the determination of V .

Now one can solve the problem of the ballistic pendulum, where the kinetic energy of the bullet/sand box system is converted into gravitational potential energy:

> Mom:=m*v0=(M+m)*V;

> V:=solve(Mom,V);

> En:=(M+m)/2*V^2=(M+m)*g*h;

> height:=solve(En,h);

We can do variations on the theme, i.e., consider other types of collisions in one dimension.

An elastic collision with different final velocities for the projectile and the target is an obvious case. Let us restart the Maple engine to reset the variables:

> restart;

> En;

Energy conservation now reads:

> En:=m/2*v0^2=m/2*v^2+M/2*V^2;

Momentum conservation now becomes:

> Mom:=m*v0=m*v+M*V;

> sol:=solve({En,Mom},{V,v});

The solution contains two sets: the first describes the initial condition (mass M at rest and mass m moving with velocity v 0), i.e., the situation before the collision. It is the second set that we are interested in.

> assign(sol[2]);

> v,V;

We could be interested in expressing the ratio of initial to final veocity of the light particle as a function of the mass ratio r := M / m :

> ratio:=simplify(subs(M=r*m,v)/v0);

> with(plots):

> semilogplot(ratio,r=1..1000);

We see that as the mass ratio M / m exceeds about 100 the motion describes essentially a reflection of the light particle m from a wall, i.e., it approaches the limit

v =- v 0.

Exercise:

Provide a graph of the ratio of V / v 0 as a function of the mass ratio. Graph the ratio of final kinetic energies of the collision partners as a function of the mass ratio.

A slightly more sophisticated problem is solved in R.L. Greene's book: Classical Mechanics with Maple (Springer 1994).

Party trick: A light and a heavy ball (masses m and M respectively) are dropped simultaneously in a gravitational field from a height h0 with m sitting on top of M initially. What height will the light ball reach?

We assume elastic collisions and ignore the acceleration by the gravitational field during the collision itself.

The first statement is energy conservation: when the two-ball system hits the ground it has converted its gravitational potential energy fully into kinetic energy:

> restart;

> En1:=(m+M)*g*h0=(m+M)/2*v0^2;

The large ball M bounces elastically from the ground, i.e., reverses its velocity to - v 0. It then collides with the small ball m that is still moving downward with v 0.

> En2:=M/2*v0^2+m/2*v0^2=M/2*V^2+m/2*v^2;

> Mom2:=M*(-v0)+m*v0=M*V+m*v;

The final height of the small ball called h is obtained from energy conservation:

> En3:=m/2*v^2=m*g*h;

We can try the simple approach, i.e., we can let Maple grind on the set of four equations.

> sol:=solve({En1,En2,Mom2,En3},h);

Our intelligence is needed...

> v0s:=solve(En1,v0);

The choice of root depends on the definition of the positive direction. If upwards is positive, we choose the negative root to describe downward motion at this point:

> v0:=v0s[2];

> sol:=solve({En2,Mom2,En3},h);

Our difficulties are not yet solved... even though v0 has been substituted:

> En2;

> solve(Mom2,V);

> V:=simplify(%);

> solve(En2,v);

There are two roots and we have to figure out which one is physically acceptable. The first describes the situation before the collision (downward motion with v0), i.e., we need the one after the collision which depends on the masses:

> v:=%[2];

> solve(En3,h);

> h:=%;

We are interested again in exploring the answer as a function of the mass ratio and eliminate the initial height:

> ratio:=simplify(subs(M=r*m,h)/h0);

> with(plots):

> semilogplot(ratio,r=1..1000);

The result is astonishing: the light ball can return to a multiple of its original height! The curve indicates a limiting behaviour. We use Maple to explore this:

> limit(ratio,r=infinity);

For mass ratios of r = M / m > 100 the maximum possible height ratio is reached. The lighter ball can reach nine times the original height from which it was dropped.

Practice the trick with various balls (tennis, ping-pong, solid rubber, etc.) before trying to impress your friends. It takes a little skill to drop the balls in such a way that they remain on top of each other when they hit the ground.

This problem has further-reaching applications in that it can explain the essence of some rather complicated phenomena in physics. One example is the problem of supernova explosions following the collapse of a star. One can think of the imploding massive star as carrying out a bounce which drives the lighter outer parts of the system through a shockwave to reach very high speeds. This mechanism results in the spilling of material (including heavy, unstable elements [nuclei beyond iron, i.e., beyond the maximum in the binding energy/nucleon curve]) into outer space at high speeds.

Of course, the conservation laws can't tell us much about the detailed dynamics of the motion. It is important to realize, however, that the differential equations which describe the detailed motion (in Mechanics it is Newton's law) have solutions which satisfy the conservation laws.

>