Compton scattering

We used conservation laws for linear momentum and kinetic energy to solve one-dimensional collision problems. In more dimensions the number of degrees of freedom associated with the particle motion exceeds the number of constraints provided conservation laws. This means that we will not be able to obtain complete solutions. Nevertheless, it is interesting to investigate the constraints supplied by the conservation laws.

Suppose that a particle of mass m is impinging with velocity v 0 along the x -axis on a particle of mass M that is initially at rest. The particles interact by a central force (force acts only along the mutual separation). To attempt a solution based on conservation laws means to not take into account the details of the interaction. A complete dynamical approach involves solving Newton's equations (or variants thereof, such as Lagrange's, or Hamilton's forms), which takes into account the force law, and which automatically obeys the conservation laws. An example of such a complete solution was the problem of firing a cannonball.

1) The conservation of angular momentum for the motion of objects subject to central forces implies that the motion is confined to a plane. This reduces the three degrees of freedom in the position vectors of the masses to two. The number of degrees of freedom is reduced from 6 to 4.

2) The conservation of energy provides one scalar constraint, i.e., 3 degrees of freedom remain.

3) The conservation of linear momentum in the scattering plane provides 2 constraints.

Thus, the problem cannot be completely determined from the conservation laws. This is illustrated in this worksheet, first in general, and then specifically for the scattering of photons off atomic electrons resulting in an energy transfer to the electron, i.e., Compton scattering.

We set up the equations for the constraints 2 and 3, i.e., we begin in the scattering plane (having made use of angular momentum conservation). We assume complete elasticity for the collision, although it is not difficult to incorporate in the energy balance a given amount of binding energy that has to be supplied to mass M in order to free it from the target.

> En:=m/2*v0^2=m/2*v^2+M/2*V^2;

To specify the momentum components after the collision we introduce two angles with respect to the x axis: theta for the scattering particle ( m ) and phi for the particle initially at rest ( M ):

> Momx:=m*v0=m*v*cos(theta)+M*V*cos(phi);

> Momy:=0=m*v*sin(theta)+M*V*sin(phi);

What are we interested in?

The masses of the particles and the initial speed v 0 are usually known.

Unknown are four quantities: v , V , and theta and phi. How can we use the three constraints to learn as much as possible about the problem?

Before we jump into the general situation, let us first consider the equal-mass case:

> En1:=subs(M=m,En);

> Momx1:=subs(M=m,Momx);

> Momy1:=subs(M=m,Momy);

Given that we have three equations we can ask for a solution for three variables:

> sol:=solve({En1,Momx1,Momy1},{v,V,theta});

Maple's solve engine finds a set of four acceptable solutions. Let us see what they imply.

Set 1 describes the situation before the collision.

Set 2 describes the mirror image of the situation in set 1.

Sets 3 and 4 assign the same speed to mass M . If we assume that theta and phi are in the range 0..Pi/2, and -Pi/2..0 respectively, i.e., both masses move to the right with m deflected in the positive y direction and M moving downward, it is clear that set 4 is the interesting case. The speed v should be positive.

An interesting conclusion can be reached:

apparently the scattering angle phi is arbitrary (in the range -Pi/2..0), and the projectile scattering angle theta is given in terms of phi. The well-known textbook result for the equal-mass elastic scattering case is obtained, namely that the two objects emerge at right angles with respect to each other.

Furthermore, given a choice of angle phi, the distribution of kinetic energies between incident and hit particle is fixed. For each scattering angle phi (or theta) the kinetic energy of both the impinging and hit object are fixed.

> assign(sol[4]);

> print(v,V);

> KEm:=m*v^2/2;

> KEM:=m*V^2/2;

> m:=1; v0:=10;

> plot([KEm,KEM],phi=-Pi/2..0,color=[blue,green],axes=BOXED);

Obviously the sum of the kinetic energies of the two masses (note M = m ) is independent of phi, as it has to equal m /2* v 0^2.

The extreme cases correspond to the following situations:

phi=0, theta=Pi/2 : the incident mass remains at rest ( KEm=0 ), and the angle theta is irrelevant. The hit particle ( M ) moves in the forward direction with maximum kinetic energy. This represents a head-on collision that can be calculated in a one-dimensional geometry.

phi=-Pi/2, theta=0 : the incident mass transfers no energy to the hit mass ( KEM=0 ), phi is irrelevant. This corresponds to the limit of a grazing collision when the particles interact only very weakly. More interesting is the observation that before the limit is reached (small-angle projectile scattering) the hit particle recoils with an angle of almost 90 degrees, and picks up a small amount of kinetic energy only.

phi=-Pi/4, theta=Pi/4 : equal sharing of energy after the collision.

We are now ready to consider the general case.

> restart;

> En:=m/2*v0^2=m/2*v^2+M/2*V^2;

> Momx:=m*v0=m*v*cos(theta)+M*V*cos(phi);

> Momy:=0=m*v*sin(theta)+M*V*sin(phi);

> sol:=solve({En,Momx,Momy},{v,V,theta});

We are now used to the fact that the initial condition and its mirror image appear as solutions to the system of equations. Let us analyze the interesting solution.

> assign(sol[3]);

> v;

> V;

> theta;

We notice that the relationship between theta and phi is more complicated. Let us first analyze the simple part. The kinetic energy of the hit particle is still a function of its scattering angle. Note that the arctan function can take two arguments (look it up in the help pages).

> KEM:=M/2*V^2;

For fixed scattering angle phi we can explore the dependence of this kinetic energy on the mass ratio.

> phi:=-Pi/4; v0:=10; m:=1; M:=r*m;

> KEM;

> KEtot:=m/2*v0^2;

We perform a semilog-plot 'by hand' and cover the range of mass ratios from 0.001 to 1000 on the abscissa.

> plot(subs(r=10^s,KEM)/KEtot,s=-3..3);

We learn from the graph that the equal-mass case is the most effective for energy transfer. If the mass ratio r = M / m is either small or large, then the fraction of the kinetic energy transferred to the mass M in collisions with phi = -45 degrees becomes very small.

The other variables that were determined looked somewhat clumsy. A square root was not carried out to avoid case distinctions. With the specification of m and v 0 they are, of course, somewhat simplified:

> v;

> simplify(v);

> evalf(subs(r=1,%));

Maple picks one of the roots, unfortunately the one with the negative sign...

Given that a simple square root is at issue we convert the RootOf to a radical expression:

> v:=convert(v,radical);

To display the fraction of the total kinetic energy remaining with mass m after the collision for the special case of phi = -45 degrees as a function of the mass ratio we calculate:

> plot(subs(r=10^s,v)^2/v0^2,s=-3..3);

Obviously, this is the complement to the previous graph. Let us observe the corresponding scattering angle for the incident particle of mass m :

> theta:=convert(theta,radical);

> plot(subs(r=10^s,theta),s=-3..3);

The equal-mass case ( s =0, r =1) results in theta=Pi/4 as expected.

In the limit of r = M / m going to zero ( s large, negative), i.e., a massive incident particle as compared to the hit particle, the scattering angle for the incident particle goes to zero (note that phi is fixed at phi=-Pi/4).

In the limit of r = M / m going to infinity ( s large, positive), i.e., a light incident particle as compared to the hit particle, the scattering angle theta approaches Pi, i.e., reflection while the heavier object exits at phi=-45 degrees. This includes the limit of a head-on collision with perfect reflection, as the previous graphs showed that in the limit of large r no energy is transferred to the heavy mass M (its exit angle phi becomes irrelevant).

Another interesting case to investigate involves fixing the energy of the hit particle and asking for the allowed range of scattering angles phi.

Finally we are ready to discuss Compton scattering .

The discussion is slightly different to take into account the fact that photons are not classical massive particles. It was observed in the passage of light through matter that some light (X rays in particular) was emitted with an increased wavelength, i.e., reduced energy. The change in wavelength depended on the scattering angle of the observed photons. Compton's explanation is based on a corpuscular model for the photons.

The problem can be set up as before, except that one needs expressions for photon energy and momentum.

The photon momentum before the collision is labeled as p 0 and given in terms of Planck's constant h, the frequency nu, and the speed of light c:

> restart;

> p0:=h*nu0/c;

The momentum conservation law can be expressed as

> Momx:=p0=h*nu/c*cos(theta)+P*cos(phi);

> Momy:=0=h*nu/c*sin(theta)+P*sin(phi);

To formulate energy conservation we need to take into account the relativistic energy-momentum relationship (in the limit of high photon energies the electron can be picking up a large amount of kinetic energy).

The kinetic energy before the collision is rest energy of the electron (it is assumed to be unbound, i.e., free, and at rest, we denote its rest mass as M ) and the photon energy:

> En:=h*nu0+M*c^2=h*nu+Eel;

Before we can solve we need to express the electron energy after the knock-out in terms of its rest mass M and its final momentum P .

> En1:=subs(Eel=sqrt(M^2*c^4+P^2*c^2),En);

> sol:=solve({Momx,Momy,En1},{nu,P,phi});

Matters are more complicated obviously...

We can eliminate the electron emission angle phi by squaring the momentum conservation equations:

> ex1:=solve(Momx,P*cos(phi));

> ex2:=solve(Momy,P*sin(phi));

> eq1:=ex1^2+ex2^2=P^2;

> eq1:=simplify(eq1);

> sol:=solve({En1,eq1},{P,nu});

> assign(sol);

> nu;

If we are just interested in the wavelength shift as a function of photon scattering angle, we do the following. First we make use of the relationship lambda*nu=c to obtain an expression for the scattered photon's wavelength:

> eq2:=nu=c/lambda;

Now we substitute the frequency nu0:

> eq3:=subs(nu0=c/lambda0,eq2);

> eq3:=simplify(eq3);

The wavelength shift Delta is given by subtracting the original wavelength lambda0 from lambda; the latter is obtained by isolating lambda in eq3.

> Delta:=simplify(solve(eq3,lambda)-lambda0);

The wavelength shift Delta does not depend on the original wavelength lambda0 and is given as a multiple of a natural length scale for the electron, namely the Compton wavelength of the electron h/(M*c). If we factor out this unit, the wavelength shift as a function of the photon scattering angle is given in the following graph:

> plot(1-cos(theta),theta=0..Pi);

The wavelength shift acquires a maximum in the backward direction. The maximum inelasticity equals twice the Compton wavelength of the particle that has been hit (in our case a free electron).

In the forward direction the photons pass through without energy transfer.

It is useful to obtain an idea about the length scale of the Compton wavelength for an electron:

> lambda[C]:=h/(M*c);

> h:=6.63*10^(-34)*_N*_m*_s; #Planck's constant in SI units

> c:=3.*10^8*_m/_s; # speed of light in SI units

> M:=9.11*10^(-31)*_kg; # electron mass in SI units

> lambda[C];

> subs(_N=_kg*_m/_s^2,%);

Thus the maximum wavelength shift that a free electron can provide equals approximately 5*10^(-12) m, or 0.05 Angstroms, or 5 picometers. To put this in relation with the photon wavelengths we note that hard X rays have wavelengths that are thousands of times shorter than those of visible light (0.1 nm vs 450-700 nm, 1 Angstrom = 0.1 nm). For hard X rays the wavelength shift thus reaches the percent range.

We conclude that soft photons can backscatter from electrons without appreciable energy loss, while hard photons can transfer a sizable amount of energy in a backscattering process. Of course, matters are in reality more complicated: soft photons can excite electrons to undergo transitions between bound states. It is just the consideration of the kinematics of elastic scattering that leads to the above conclusion.

>