Rocket propulsion

The problem of mechanical systems in one dimension with varying mass represents an interesting application of Newton's law. It comes up in the rocket problem (variable mass and velocity), the conveyor belt problem, and others. (cf. K. Symon: Mechanics , 3rd ed. p. 172ff, L.S. Lerner: Physics , p. 226 ff, or almost any first-year physics text).

We consider a rocket without external forces (no gravity). The rocket's momentum for motion in one dimension is given as:

> P_R:=M(t)*v(t);

Here v ( t ) is the velocity of the rocket with respect to a stationary frame. The rocket is propelled by the exhaust of gases with a constant velocity u relative to the rocket. With respect to the stationary (laboratory) frame the exhaust gas has a velocity of v + u . The total rate of change of momentum has to vanish, as there are no external forces. Thus, the total rate of change of the rocket's momentum is balanced by the rate of change of the exhaust gas momentum. The latter is given by the change in mass times the exhaust velocity in the lab frame.

> NEq:=diff(P_R,t)-diff(M(t),t)*(v(t)+u)=0;

> NEq:=simplify(NEq);

It appears, as if there is an asymmetry in how the velocity v ( t ) is treated: in the rate of change of the rocket momentum derivatives are considered both for the mass and for the velocity. They are both important as they are multiplied by the other respective variable (as dictated by the product rule). In the rate of change of the exhaust fuel momentum it appears as if the change in part of the velocity in the lab frame (namely in v ( t )) is ignored. This is indeed the case, but it is justified since the velocity is multiplied at each instant in time by a small amount of mass: between time layers t and t +d t the only mass that counts on the exhaust gas side is d M . One is justified to ignore the change in velocity d v as the product d m d v is of higher order and does not come into play. It is in fact cancelled by a similar term arising in the rocket momentum at t +d t which expressed with differentials reads as

( M +d M )*( v +d v ).

We can solve the differential equation either for the mass or for the velocity as a function of time:

> solM:=dsolve(NEq,M(t));

> solv:=dsolve(NEq,v(t));

In the solution for the mass M ( t ) the integration constant _C1 is clearly a mass, namely

M ( t =0)= M (0).

In the second solution for v(t) some further thinking is required. It makes no sense to take the logarithm of a dimensionful quantity (e.g. a mass). Thus _C1 should really be reexpressed as a constant that represents - u ln( M ( t =0)), in which case the solution can be expressed as

u ln( M ( t )/ M (0)). Now the logarithm is taken of a dimensionless quantity, which makes sense.

Note that u is the exhaust velocity (not just the speed), i.e., the direction is opposite to the rocket velocity v ( t ).

With specified initial conditions the solution for the velocity is obtained as:

> solv:=dsolve({NEq,v(0)=v0},v(t));

The fact that the solution can be found either for M ( t ) or for v ( t ) should have made us suspicious. The solution for v ( t ) depends on the time evolution of M ( t ) and vice versa. This makes sense, as we have specified the exhaust velocity (or speed) of the gas, but not the rate at which the fuel is being burned. The rocket velocity depends clearly on how much mass is being sent off in the opposite direction at a given exhaust speed. Let us assume a linear relationship with m being the mass of the rocket without fuel, and a valid time range of 0 < t < 10 (all quantities in MKSA (SI) units):

> m:=500;

> M:=t->m+1000-100*t;

> v_R:=unapply(rhs(solv),u,v0,t);

> plot(v_R(-100,0,t),t=0..10);

For t > t_f = 10 the solution is not meaningful since the fuel contribution to M ( t ) becomes negative according to the mapping given above.

The acceleration of the rocket changes as a function of time. It is calculated by differentiating the velocity:

> v_R(-100,0,t);

> a_R:=diff(%,t);

> plot(a_R,t=0..10);

The strong rise in the rocket's acceleration near the end of the fuel burn cycle is associated with the fact that according to the solution the increase in velocity d v is given by the product of the exhaust speed and the log of the mass ratio ( M ( t +d t )/ M ( t )). The mass ratio is close to unity while a lot of heavy fuel is on board, but deviates strongly from that value as the fuel is exhausted.

Another interesting observation can be made from the graph of the acceleration at early times The rocket starts with a positive non-zero acceleration. If we add the gravitational acceleration that acts in the opposite direction we may not have enough thrust for lift-off. We discuss thrust further below: it is the magnitude of the equivalent force that results as a consequence of hurling out particles at a given flow rate (d M /d t ) with some exhaust speed | u |. The product of these two quantities has the dimensions of a force and it is responsible for the rocket's acceleration. For a constant rate of fuel burn-up and for constant exhaust speed this force is constant. Thus, the increase in the rockets acceleration during its fuel-burning phase is a result of the decreasing rocket mass. Multi-stage rockets have the advantage that the mass associated with a big motor (or entire booster rockets on the Space Shuttle) can be jettisoned as the contained fuel is burned up. For the subsequent stage(s) a more convenient fuel/gross payload ratio can be achieved.

The design of rockets calls for a thrust that is several times larger than the initial weight in order to gain speed quickly. When a rocket is ignited, however, it takes some time for the build-up of full thrust: this is repsonsible for a short delay between firing of engines and lift-off. For the example given above the product of fuel burning rate and exhaust velocity, i.e., the thrust is not enough to overcome gravity (the acceleration does not exceed 9.8 m/s^2). In free space, however, this issue is not important.

A similar phenomenon can be experienced during take-off of jet airplanes, i.e., a time delay between the revving up of engines and actual forward acceleration (here one needs to overcome friction to set the plane in motion). In a jet engine thrust is not achieved by just hurling burned fuel out of a nozzle: air is taken in and compressed by burning kerosene using air from the intake.

If we do not like to rely on Maple's dsolve engine, we can perform the required steps to find the solution ourselves. We restart the session and redefine Newton's equation as it is safer than to simply unassign M ( t ) (we found this to be unreliable in early releases of Maple V):

> restart;

> NEq:=simplify(diff(M(t)*v(t),t)-diff(M(t),t)*(v(t)+u)=0);

> accel:=solve(NEq,diff(v(t),t));

> sol:=v(s)-v(0)=int(accel,t=0..s);

To combine the solution to the Tsiolkovski formula (named after a rocket pioneer who found it in 1897) we need some tricks: it is necessary to assume the arguments of the ln function to be positive for the combine command to work; the assumption of positive M doesn't work properly as it is a subscripted variable, so we substitute two symbols for the initial and final mass, factor the expression and then combine:

> assume(M_f>0,M_i>0); interface(showassumed=0);

> Delta:=combine(factor(subs(M(s)=M_f,M(0)=M_i,rhs(sol))),ln);

The interpretation of this expression for the change in the rocket velocity Delta for given exhaust velocity u is as follows:

The mass ratio that appears as the argument of the logarithm is less then unity, and thus the logarithm yields a negative number. This is consistent with the fact that the rocket acquires a change in velocity of opposite sign to the exhaust velocity. If u were to stand for the exhaust speed, the mass ratio would need to be inverted. Note that the formula is valid for any finite time interval, as it represents the solution to the differential equation. In particular, it is not important how the fuel was burned, i.e., whether M ( t ) was linear in time as assumed for the graph of the solution above.

>